Revista do CD-ROM 101/CD-ROM 101.iso/compl/maya5ple/Install_MayaPLE5_English.exe/Maya/Data1.cab/performGeometryConstraint.me

Text File | 2003-07-17 | 7.6 KB | 331 lines

// Copyright (C) 1997-2002 Alias|Wavefront,
// a division of Silicon Graphics Limited.
//
// The information in this file is provided for the exclusive use of the
// licensees of Alias|Wavefront.  Such users have the right to use, modify,
// and incorporate this code into other products for purposes authorized
// by the Alias|Wavefront license agreement, without fee.
//
// ALIAS|WAVEFRONT DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
// INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
// EVENT SHALL ALIAS|WAVEFRONT BE LIABLE FOR ANY SPECIAL, INDIRECT OR
// CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
// DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
// TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
// PERFORMANCE OF THIS SOFTWARE.
//
//
//  Alias|Wavefront Script File
//  MODIFY THIS AT YOUR OWN RISK
//
//  Creation Date:  18 July 1997
//
//  Description:
//        This script provides an option box dialog for the geometryConstraint command.
//
//    Input Arguments:
//        boolean showOptionBox    true - show the option box dialog
//                                false - just execute the command
//
//
//  Procedure Name:
//      setOptionVars
//
//  Description:
//        Initialize the option values.
//
//  Input Arguments:
//        Whether to set the options to default values.
//
//  Return Value:
//      None.
//
proc setOptionVars(int $forceFactorySettings)
{
    //    weight
    //
    if ($forceFactorySettings || !`optionVar -exists geometryConstraintWeight`) {
        optionVar -floatValue geometryConstraintWeight 1.0;
    }
}

//
//  Procedure Name:
//      geometryConstraintSetup
//
//  Description:
//        Update the state of the option box UI to reflect the option values.
//
//  Input Arguments:
//      parent               - Top level parent layout of the option box UI.
//                             Required so that UI object names can be
//                             successfully resolved.
//
//        forceFactorySettings - Whether the option values should be set to
//                             default values.
//
//  Return Value:
//      None.
//
global proc geometryConstraintSetup(string $parent, int $forceFactorySettings)
{
    //    Retrieve the option settings
    //
    setOptionVars($forceFactorySettings);

    setParent $parent;

    //    Query the optionVar's and set the values into the controls.

    //    weight
    //
    floatSliderGrp -edit
        -value `optionVar -query geometryConstraintWeight`
        geometryConstraintWeight;

}

//
//  Procedure Name:
//      geometryConstraintCallback
//
//  Description:
//        Update the option values with the current state of the option box UI.
//
//  Input Arguments:
//      parent - Top level parent layout of the option box UI.  Required so
//               that UI object names can be successfully resolved.
//
//        doIt   - Whether the command should execute.
//
//  Return Value:
//      None.
//
global proc geometryConstraintCallback(string $parent, int $doIt)
{
    setParent $parent;

    //    Set the optionVar's from the control values, and then
    //    perform the command.

    //    weight
    //
    optionVar -floatValue geometryConstraintWeight
        `floatSliderGrp -query -value geometryConstraintWeight`;

    if ($doIt) {
        performGeometryConstraint 0;
        addToRecentCommandQueue "performGeometryConstraint 0" "GeometryConstraint";
    }
}

//
//  Procedure Name:
//     geometryConstraintOptions
//
//  Description:
//        Construct the option box UI.  Involves accessing the standard option
//        box and customizing the UI accordingly.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//
proc geometryConstraintOptions()
{
    //    Name of the command for this option box.
    //
    string $commandName = "geometryConstraint";

    //    Build the option box actions.
    //
    string $callback = ($commandName + "Callback");
    string $setup = ($commandName + "Setup");

    //    Get the option box.
    //
    string $layout = getOptionBox();
    setParent $layout;

    //    Pass the command name to the option box.
    //
    setOptionBoxCommandName($commandName);

    //    Activate the default UI template.
    //
    setUITemplate -pushTemplate DefaultTemplate;

    //    Turn on the wait cursor.
    //
    waitCursor -state 1;

    tabLayout -scr true -tv false;
    string $parent = `columnLayout -adjustableColumn 1`;

    floatSliderGrp -label "Weight"
        -field true -min 0.0 -max 10.0
        geometryConstraintWeight;

    //    Turn off the wait cursor.
    //
    waitCursor -state 0;

    //    Deactivate the default UI template.
    //
    setUITemplate -popTemplate;

    //    'Apply' button.
    //
    string $applyBtn = getOptionBoxApplyBtn();
    button -edit
        -label "Add"
        -command ($callback + " " + $parent + " " + 1)
        $applyBtn;

    //    'Save' button.
    //
    string $saveBtn = getOptionBoxSaveBtn();
    button -edit
        -command ($callback + " " + $parent + " " + 0 + "; hideOptionBox")
        $saveBtn;

    //    'Reset' button.
    //
    string $resetBtn = getOptionBoxResetBtn();
    button -edit
        -command ($setup + " " + $parent + " " + 1)
        $resetBtn;

    //    Set the option box title.
    //
    setOptionBoxTitle("Geometry Constraint Options");

    //    Step 8: Customize the 'Help' menu item text.
    //    ============================================
    //
    setOptionBoxHelpTag( "Geometry" );

    //    Set the current values of the option box.
    //
    eval (($setup + " " + $parent + " " + 0));

    //    Show the option box.
    //
    showOptionBox();
}

//
//  Procedure Name:
//      geometryConstraintHelp
//
//  Description:
//        Return a short description about this command.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      string.
//
proc string geometryConstraintHelp()
{
    // ******** Example
    // "  Command: Extrude - create a surface using extrusion.\n" +
    // "Selection: curves and isoparms."

    return
    "  Command: geometryConstraint - constrain one object to lie on surface of another\n" +
    "Selection: One or more transforms or shapes followed by a transform";
}

//
//  Procedure Name:
//      assembleCmd
//
//  Description:
//        Construct the command that will apply the option box values.
//
//  Input Arguments:
//      None.
//
//  Return Value:
//      None.
//
proc string assembleCmd()
{
    string $cmd = "geometryConstraint";

    setOptionVars(false);

    $cmd = ($cmd
            + " -weight " + `optionVar -query geometryConstraintWeight`);

    return $cmd;
}

//
//  Procedure Name:
//      performGeometryConstraint
//
//  Description:
//        Perform the geometryConstraint command using the corresponding
//        option values.  This procedure will also show the option box
//        window if necessary as well as construct the command string
//        that will invoke the geometryConstraint command with the current
//        option box values.
//
//  Input Arguments:
//      0 - Execute the command.
//      1 - Show the option box dialog.
//      2 - Return the command.
//
//  Return Value:
//      None.
//
global proc string performGeometryConstraint(int $action)
{
    string $cmd = "";

    switch ($action) {

        //    Execute the command.
        //
        case 0:
            //    Retrieve the option settings
            //
            setOptionVars(false);

            //    Get the command.
            //
            $cmd = `assembleCmd`;

            //    Execute the command with the option settings.
            //
            evalEcho($cmd);

            break;

        //    Show the option box.
        //
        case 1:
            geometryConstraintOptions;
            break;

        //    Return the command string.
        //
        case 2:
            //    Retrieve the option settings.
            //
            setOptionVars (false);

            //    Get the command.
            //
            $cmd = `assembleCmd`;
            break;
    }
    return $cmd;
}